Google Analytics Data Export API

This is example to get the profiles list & data from the command line by using cUrl

1. Download Curl: http://curl.haxx.se/download/curl-7.19.4-win32-ssl-sspi.zip

2. Create a Bat File, and save it (for example getAccountList.bat):

@echo off
echo.
echo Google Analytics BAT file
echo -------------------------------------
echo 1. First you need to login to get your profile list
echo.
	set accountType=HOSTED_OR_GOOGLE
	set /p accountType=	Account Type [Default:HOSTED_OR_GOOGLE] :
	     set /p Email=	Email Address				:
	   set /p Passwd=	Password				:

set url="AccountType=%accountType%&Email=%email%&Passwd=%passwd%&service=analytics&source=testing.bat"
	curl --silent -d %url% -k https://www.google.com/accounts/clientLogin | find "Auth" > token
	set /p Token= <token
	del token

curl --silent -H "Authorization: GoogleLogin %token%" -k https://www.google.com/analytics/feeds/accounts/default?prettyprint=true >ans

echo.
echo @echo off>ans.bat
echo if "%%1"=="title" set toprint=%%4 >> ans.bat
echo if "%%1"=="dxp:tableId" echo          %%2	:%%toprint%% >> ans.bat
echo 2. Choose a profile from the list:
for /f "tokens=1-10 delims=<,>, " %%a in (ans) do @call ans.bat %%a %%b %%c %%d %%e %%f

echo.
set /p profileId=	Please Choose Profile [ga:xxxxxxx] :
echo.

echo 3. Fill details about the profile you ask:
echo.
set start-date=2009-01-01
set end-date=2009-01-31
set dimensions=ga:date
set metrics=ga:pageviews

set /p start-date=	Start Date [Default: 2009-01-01]:
set /p end-date=	End Date [Default: 2009-02-01]	:
set /p dimensions=	Dimenstions [Default: 'ga:date']:
set /p metrics=	Metrics[Default: 'ga:pageviews']:

curl --silent -H "Authorization: GoogleLogin %token%" -k "https://www.google.com/analytics/feeds/data?ids=%profileId%&dimensions=%dimensions%&metrics=%metrics%&start-date=%start-date%&end-date=%end-date%&start-index=1&prettyprint=true" >ans

echo @echo off >ans.bat
echo if "%%1"=="dxp:dimension" set toprint=%%5 >>ans.bat
echo if "%%1"=="dxp:metric" echo          %%toprint%%:%%9 >>ans.bat
echo if "%%1"=="dxp:metric" set toprint=>>ans.bat

echo.
echo 4. Results:
echo ---------------------
for /f "tokens=1-10 delims=<>/' " %%a in (ans) do @call ans %%a %%b %%c %%d %%e %%f %%g %%h %%i %%j

del ans.bat
del ans
set token=
set email=
set passwd=
set accountType=
set dimensions=
set metrics=
set url=
set end-date=
sel start-date=
set toprint=

Screen shots:

Read more: Google Analytics Data Export API
Other Library: Google Contact API by using cUrl in BAT file